request = require 'request'
_ = require('underscore')._
ltx = require 'ltx'

parse_xml = (xml, callback) ->
  try ltx.parse(xml)
  catch err
    callback(err)
    null

class Client

  constructor: (host = "localhost", port = 10025) ->
    @server_url = "http://#{host}:#{port}/"

  @get: (path, async_filter) ->
    (cb) ->
      throw new Error("No callback passed !") unless cb
      @request path, (err, resp) ->
        return cb(err) if err
        if async_filter
          async_filter(resp, cb)
        else
          cb null, resp

  @feature_switch = (feature, path) ->
    switch_fn = (enable, callback) -> @request "#{path}#{!!enable}", callback
    @prototype["set_#{feature}_enabled"] = switch_fn
    @prototype["enable_#{feature}"]  = (callback) -> switch_fn.call(this, yes, callback)
    @prototype["disable_#{feature}"] = (callback) -> switch_fn.call(this, no,  callback)

  @as_number: (value, callback) -> callback(null, parseInt(value, 10))

  @as_boolean: (value, callback) ->
    value = switch value
      when 'true',  '1', 'on',  'yes' then true
      when 'false', '0', 'off', 'no'  then false
      else value
    callback null, value

  whitespace_nodes = (el) -> typeof el == 'string' && /\s+/.test el

  hash_prefix_remover = (prefix) -> (cumbersome_hash) ->
    injector = (hash, value, key) ->
      hash[key.replace prefix, ''] = value
      hash
    _(cumbersome_hash).reduce(injector, {})

  @parse_configuration = (xml, callback) ->
    root = parse_xml xml, callback
    return unless root
    config = _(root.children).detect( (el) -> typeof el != 'string').attrs
    callback(null, config)

  @parse_downloads = (xml, callback) ->
    root = parse_xml xml, callback
    return unless root
    packages = _(root.children)
      .chain()
      .reject(whitespace_nodes)
      .pluck('attrs')
      .map(hash_prefix_remover /^package_/)
      .value()
    callback(null, packages)

  parse_link_analysis = (xml, callback) ->
    root = parse_xml xml, callback
    return unless root #TODO: change this to keep the normal control flow
    adapt_link_nodes = (link_node) ->
      link = link_node.attrs
      link.files = _(link_node.children).chain()
        .reject(whitespace_nodes)
        .pluck('attrs')
        .map(hash_prefix_remover /^file_/).value()
      link
    results = _(root.children).chain()
      .reject(whitespace_nodes)
      .map(adapt_link_nodes)
      .value()
    callback(null, results)

  help:               @get 'help'

  ip:                 @get 'get/ip'

  current_speed:      @get 'get/speed', @as_number

  config:             @get 'get/config', @parse_configuration

  version:            @get 'get/version'

  rc_version:         @get 'get/rcversion'

  get_speedlimit:     @get 'get/speedlimit'

  get_autoreconnect:  @get 'get/isreconnect', @as_boolean

  download_status:    @get 'get/downloadstatus'

  start_downloads:    @get 'action/start'
  pause_downloads:    @get 'action/pause'
  stop_downloads:     @get 'action/stop'
  toggle_downloads:   @get 'action/toggle'

  current_downloads_count:  @get 'get/downloads/current/count',  @as_number
  finished_downloads_count: @get 'get/downloads/finished/count', @as_number
  downloads_count:          @get 'get/downloads/all/count',      @as_number

  current_downloads_list:  @get 'get/downloads/current/list',    @parse_downloads
  finished_downloads_list: @get 'get/downloads/finished/list',   @parse_downloads
  downloads_list:          @get 'get/downloads/all/list',        @parse_downloads

  check_links: (links, cb) ->
    links_list = links.join('\n')
    path = "special/check/#{encodeURI links_list}"
    @request path, (err, resp) =>
      return cb(err) if err
      parse_link_analysis resp, cb

  add_downloads: (links, cb) ->
    links_list = links.join('\n')
    path = "action/add/links/#{encodeURI links_list}"
    @request path, cb

  purge_downloads: @get 'action/downloads/removeall'

  remove_downloads: (package_names, cb) ->
    package_names = package_names.join('/')
    path = "action/downloads/remove/#{escape package_names}"
    @request path, cb

  webupdate: @get 'action/update'
  force_webupdate: @get 'action/forceupdate'

  reconnect: @get 'action/reconnect'
  restart:   @get 'action/restart'
  shutdown:  @get 'action/shutdown'

  set_speedlimit: (new_limit, callback) ->
    "action/set/download/limit/#{new_limit}"

  remove_speedlimit: (callback) -> set_speedlimit 0, callback

  set_max_downloads: (count, callback) ->
    "action/set/download/max/#{count}"

  set_download_dir: (directory, callback) ->
    @request "action/set/downloaddir/general/#{escape directory}", callback

  @feature_switch 'grabber_autoadding', "set/grabber/autoadding/"

  @feature_switch 'grabber_startafteradding', "set/grabber/startafteradding/"

  @feature_switch 'reconnect', 'action/set/reconnect/'
  @feature_switch 'premium', 'action/set/premiumenabled/'

  request: (path, callback) ->
    request
      uri: @server_url + path
      callback: (error, response, body) =>
        if error
          error.response = response
          error.body = body
          callback error
        else
          callback null, body, response.statusCode

exports.Client = Client