--Author: Venkata Potluri
--Date: May 08, 2015

DECLARE
   TYPE T_TXN_ID IS TABLE OF SIEBEL_PURGE.FIX_ACRL_MEM_ID.TXN_ID%TYPE;

   TYPE T_TMEM_ID IS TABLE OF SIEBEL_PURGE.FIX_ACRL_MEM_ID.T_MEM_ID%TYPE;

   TYPE T_ACRL_ID IS TABLE OF SIEBEL_PURGE.FIX_ACRL_MEM_ID.ACRL_ID%TYPE;

   TYPE T_AMEM_ID IS TABLE OF SIEBEL_PURGE.FIX_ACRL_MEM_ID.A_MEM_ID%TYPE;


   ARR_TXN_ID    T_TXN_ID;
   ARR_TMEM_ID   T_TMEM_ID;
   ARR_ACRL_ID   T_ACRL_ID;
   ARR_AMEM_ID   T_AMEM_ID;
   LOG_ROW_ID    NUMBER := 0;
   ROW_COUNT     NUMBER := 0;

   CURSOR C1
   IS
      --SELECT /*+ index_ffs(t,temp_txn_mem_u1) parallel(a,10) */ T.TXN_ID,
	  SELECT /*+ index_ffs(t,temp_txn_mem_u1) parallel(a,5) */ T.TXN_ID,
             T.T_MEM_ID,
             A.ROW_ID,
             A.MEMBER_ID
        FROM SIEBEL_PURGE.TEMP_TXN_MEM T
             INNER JOIN SIEBEL.S_LOY_ACRL_ITM A ON T.TXN_ID = A.TXN_ID
       WHERE T.T_MEM_ID <> A.MEMBER_ID;
BEGIN
   SELECT CASE WHEN MAX (ROW_ID) IS NOT NULL THEN MAX (ROW_ID) + 1 ELSE 1 END
     INTO LOG_ROW_ID
     FROM SIEBEL_PURGE.PURGE_LOG;

   INSERT INTO SIEBEL_PURGE.PURGE_LOG (ROW_ID, PROCESS_NAME, START_TIME)
      SELECT LOG_ROW_ID, 'Fix S_LOY_ACRL_ITM MEMBER_IDs Part-1/2', SYSDATE
        FROM DUAL;

   COMMIT;

   OPEN C1;

   LOOP
      FETCH C1
         BULK COLLECT INTO ARR_TXN_ID,
              ARR_TMEM_ID,
              ARR_ACRL_ID,
              ARR_AMEM_ID
         LIMIT 1000;

      FORALL ROW IN ARR_ACRL_ID.FIRST .. ARR_ACRL_ID.LAST
         INSERT INTO SIEBEL_PURGE.FIX_ACRL_MEM_ID (TXN_ID,
                                                   T_MEM_ID,
                                                   ACRL_ID,
                                                   A_MEM_ID)
              VALUES (ARR_TXN_ID (ROW),
                      ARR_TMEM_ID (ROW),
                      ARR_ACRL_ID (ROW),
                      ARR_AMEM_ID (ROW));

      ROW_COUNT := ROW_COUNT + SQL%ROWCOUNT;

      UPDATE SIEBEL_PURGE.PURGE_LOG
         SET PROCESSED_ROWS = ROW_COUNT
       WHERE ROW_ID = LOG_ROW_ID;

      COMMIT;

      EXIT WHEN C1%NOTFOUND;
   END LOOP;

   CLOSE C1;

   UPDATE SIEBEL_PURGE.PURGE_LOG
      SET END_TIME = SYSDATE, PROCESSED_ROWS = ROW_COUNT
    WHERE ROW_ID = LOG_ROW_ID;

   COMMIT;
END;
/

QUIT