--Author: Venkata Potluri
--Date: April 08, 2015

DECLARE
   TYPE T_RDM_ID IS TABLE OF SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM.RDM_ID%TYPE;

   TYPE T_ACRL_ID
      IS TABLE OF SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM.NEW_ACRL_ID%TYPE;

   ARR_RDM_ID    T_RDM_ID;
   ARR_ACRL_ID   T_ACRL_ID;
   LOG_ROW_ID    NUMBER := 0;
   ROW_COUNT     NUMBER := 0;

   CURSOR C1
   IS
        SELECT /*+ parallel(P,12) full(P) index_ffs(R,S_LOY_RDM_ITM_P1) parallel_index(R,S_LOY_RDM_ITM_P1,12)  */
              P.RDM_ID, P.NEW_ACRL_ID
          FROM SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM P
               INNER JOIN SIEBEL.S_LOY_RDM_ITM R
                  ON P.RDM_ID = R.ROW_ID AND P.TASK_NUM = 2
      ORDER BY P.ORDER_NUM;
BEGIN
   SELECT CASE WHEN MAX (ROW_ID) IS NOT NULL THEN MAX (ROW_ID) + 1 ELSE 1 END
     INTO LOG_ROW_ID
     FROM SIEBEL_PURGE.PURGE_LOG Z;

   INSERT INTO SIEBEL_PURGE.PURGE_LOG (ROW_ID, PROCESS_NAME, START_TIME)
      SELECT LOG_ROW_ID, 'Update S_LOY_RDM_ITM Task 2', SYSDATE FROM DUAL;

   COMMIT;

   OPEN C1;

   LOOP
      FETCH C1 BULK COLLECT INTO ARR_RDM_ID, ARR_ACRL_ID LIMIT 10000;
	  --FETCH C1 BULK COLLECT INTO ARR_RDM_ID, ARR_ACRL_ID LIMIT 50;

      FORALL ROW IN ARR_RDM_ID.FIRST .. ARR_RDM_ID.LAST
         UPDATE SIEBEL.S_LOY_RDM_ITM
            SET ACCRUAL_ITEM_ID = ARR_ACRL_ID (ROW)
          WHERE ROW_ID = ARR_RDM_ID (ROW);

      ROW_COUNT := ROW_COUNT + SQL%ROWCOUNT;

      UPDATE SIEBEL_PURGE.PURGE_LOG
         SET PROCESSED_ROWS = ROW_COUNT
       WHERE ROW_ID = LOG_ROW_ID;

      COMMIT;

      EXIT WHEN C1%NOTFOUND;
   END LOOP;

   CLOSE C1;

   UPDATE SIEBEL_PURGE.PURGE_LOG
      SET END_TIME = SYSDATE, PROCESSED_ROWS = ROW_COUNT
    WHERE ROW_ID = LOG_ROW_ID;

   COMMIT;
END;
/

QUIT