--Author: Venkata Potluri
--Date: Oct 20, 2015
--1.26 mins

DECLARE
   TYPE T_MEM_ID
      IS TABLE OF SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM_10012012.MEM_ID%TYPE;

   TYPE T_RDM_ID
      IS TABLE OF SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM_10012012.RDM_ID%TYPE;

   TYPE T_ACRL_ID
      IS TABLE OF SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM_10012012.NEW_ACRL_ID%TYPE;

   ARR_MEM_ID    T_MEM_ID;
   ARR_RDM_ID    T_RDM_ID;
   ARR_ACRL_ID   T_ACRL_ID;
   LOG_ROW_ID    NUMBER := 0;
   ROW_COUNT     NUMBER := 0;

   CURSOR C1
   IS
      SELECT A.MEMBER_ID, P.RDM_ID, A.ROW_ID
        FROM SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM_10012012 P
             INNER JOIN SIEBEL.S_LOY_ACRL_ITM A
                ON A.ITEM_NUM LIKE 'PAC%' AND A.MEMBER_ID = P.MEM_ID
       WHERE P.ORDER_NUM IS NULL;
BEGIN
   SELECT CASE WHEN MAX (ROW_ID) IS NOT NULL THEN MAX (ROW_ID) + 1 ELSE 1 END
     INTO LOG_ROW_ID
     FROM SIEBEL_PURGE.PURGE_LOG_10012012;

   INSERT INTO SIEBEL_PURGE.PURGE_LOG_10012012 (ROW_ID,
                                                PROCESS_NAME,
                                                START_TIME)
      SELECT LOG_ROW_ID,
             'Update P_INT_S_LOY_RDM_ITM_10012012 with CT row_id',
             SYSDATE
        FROM DUAL;

   COMMIT;

   OPEN C1;

   LOOP
      FETCH C1
         BULK COLLECT INTO ARR_MEM_ID, ARR_RDM_ID, ARR_ACRL_ID
         LIMIT 10000;

      FORALL ROW IN ARR_RDM_ID.FIRST .. ARR_RDM_ID.LAST
         UPDATE SIEBEL_PURGE.P_INT_S_LOY_RDM_ITM_10012012
            SET NEW_ACRL_ID = ARR_ACRL_ID (ROW)
          WHERE MEM_ID = ARR_MEM_ID (ROW) AND RDM_ID = ARR_RDM_ID (ROW);

      ROW_COUNT := ROW_COUNT + SQL%ROWCOUNT;

      UPDATE SIEBEL_PURGE.PURGE_LOG_10012012
         SET PROCESSED_ROWS = ROW_COUNT
       WHERE ROW_ID = LOG_ROW_ID;

      COMMIT;

      EXIT WHEN C1%NOTFOUND;
   END LOOP;

   CLOSE C1;

   UPDATE SIEBEL_PURGE.PURGE_LOG_10012012
      SET END_TIME = SYSDATE, PROCESSED_ROWS = ROW_COUNT
    WHERE ROW_ID = LOG_ROW_ID;

   COMMIT;
END;
/

QUIT