projectzUtil = require('./projectz-util')
badgeUtil = require('./badge-util')

module.exports = backerUtil =

	getSponsorsText: (opts) ->
		result = ''

		if opts.sponsors.length is 0

			result += "No sponsors yet! Will you be the first?\n\n"
			result += badgeUtil.getTypedBadges('donation', opts)
		else
			result += "These amazing people have contributed finances to this project:\n\n"
			result += '- '+(projectzUtil.getPersonText(sponsor)  for sponsor in opts.sponsors).join('\n- ')
			result += "\n\nBecome a sponsor!\n\n#{badgeUtil.getTypedBadges('donation', opts)}"
		return result

	getMaintainersText: (opts) ->
		result = ''

		if opts.maintainers.length is 0

			result += "No maintainers yet! Will you be the first?"
		else
			result += "These amazing people are maintaining this project:\n\n"
			result += '- '+(projectzUtil.getPersonText(maintainer)  for maintainer in opts.maintainers).join('\n- ')

		return result

	getContributorsText: (opts) ->
		result = ''

		if opts.contributors.length is 0

			result += "No contributors yet! Will you be the first?"
			result += "\n#{backerUtil.getContributeText(opts)}"
		else
			result += "These amazing people have contributed code to this project:\n\n"
			result += '- '+(projectzUtil.getPersonText(contributor)+" - [view contributions](https://github.com/#{opts.repo}/commits?author=#{contributor.username})"  for contributor in opts.contributors).join('\n- ')
			result += "\n\n#{backerUtil.getContributeText(opts, 'Become a contributor!')}"

		return result

	getContributeText: (opts, text) ->

		file = 'CONTRIBUTING.md'
		url = projectzUtil.getFileUrl(opts, file)
		text ?= "Discover how you can contribute by heading on over to the `#{file}` file."

		return "[#{text}](#{url})"

	getBackerSection: (opts={}) ->

		return '' if !opts.licenses

		result = """

			#{backerUtil.getMaintainersText(opts)}

			#{backerUtil.getSponsorsText(opts)}

			#{backerUtil.getContributorsText(opts)}
			"""

		return result

	getBackerFile: (opts={}) ->

		return '' if !opts.licenses

		result = """

			#{backerUtil.getMaintainersText(opts)}

			#{backerUtil.getSponsorsText(opts)}

			#{backerUtil.getContributorsText(opts)}
			"""

		return result

	getContributeSection: (opts) ->

		result = """

			#{backerUtil.getContributeText(opts)}
			"""

		return result