badge-util.coffee

module.exports = badgeUtil =
	miscBadges:

		travis: (opts={}) ->

			return ''  if !opts.badges.travis or !opts.username or !opts.name

			return """
				[![Build Status](http://img.shields.io/travis-ci/#{opts.username}/#{opts.name}.png?branch=master)](http://travis-ci.org/#{opts.username}/#{opts.name} "Check this project's build status on TravisCI")
				"""

		npm: (opts={}) ->

			return ''  if !opts.badges.npm or !opts.name

			return """
				[![NPM version](http://badge.fury.io/js/#{opts.name}.png)](https://npmjs.org/package/#{opts.name} "View this project on NPM")
				"""

	donationBadges:

		gittip: (opts={}) ->

			return ''  if !opts.badges.gittip
			url = "https://www.gittip.com/#{opts.badges.gittip}/"

			return """
				[![Gittip donate button](http://img.shields.io/gittip/#{opts.badges.gittip}.png)](#{url} "Donate weekly to this project using Gittip")
				"""

		flattr: (opts={}) ->

			return ''  if !opts.badges.flattr
			url = "http://flattr.com/thing/#{opts.badges.flattr}"

			return """
				[![Flattr donate button](http://img.shields.io/flattr/donate.png?color=yellow)](#{url} "Donate monthly to this project using Flattr")
				"""

		paypal: (opts={}) ->

			return ''  if !opts.badges.paypal
			url = "https://www.paypal.com/cgi-bin/webscr?cmd=_s-xclick&hosted_button_id=#{opts.badges.paypal}"

			return """
				[![PayPayl donate button](http://img.shields.io/paypal/donate.png?color=yellow)](#{url} "Donate once-off to this project using Paypal")
				"""

	getBadgesSection: (opts={}) ->
		return badgeUtil.getTypedBadges('misc', opts)+'\n'+badgeUtil.getTypedBadges('donation', opts)

	getTypedBadges: (type, opts={}) ->

		results = []

		for own name,fn of badgeUtil[type+'Badges']
			result = fn.call(@, opts)
			results.push(result)  if result

		return results.join('\n')