projectz-util.coffee

typeChecker = require('typechecker')

module.exports = projectzUtil =

	getPersonText: (person) ->
		return person.markdown or person.text or person

	getFileUrl: (opts, filename) ->
		url = "https://github.com/#{opts.username}/#{opts.name}/blob/master/#{filename}#files"
		return url

	getFunctionNamed: (str) ->

		str = str.toLowerCase()

		for own name,fn of @
			if name.substr(3).substr(str.length*-1).toLowerCase() is str
				return fn

		return null

	getFunctionsEndingWith: (str) ->

		fns = []

		for own name,fn of @
			if name.substr(str.length*-1) is str
				fns.push(fn)

		return fns

	replaceSection: (names, source, inject) ->
		if typeChecker.isArray(names)
			regexName = '('+names.join('|')+')'
			sectionName = names[0]
		else
			regexName = sectionName = names

		sectionName = sectionName.toUpperCase()

		regex = ///
			\n(
				<!--\s*#{regexName}\s*-->
				|
				<!--\s*#{regexName}/\s*-->
				[\s\S]*?
				<!--\s*/#{regexName}\s*-->
			)\s*
			///gim

		replace = """
			\n<!-- #{sectionName}/ -->\n\n#{inject}\n\n<!-- /#{sectionName} -->\n\n\n
			"""

		result = source.replace(regex, replace)

		return result