title Extra lives
author Rosden Shadow [Mark Signorelli]
homepage rosden.itch.io

noaction
run_rules_on_level_Start

background_color #231F26

text_color #F2F2AA

again_interval 0.1
========
OBJECTS
========

Background
#423D39 #231F26 (#E57ED5 #CC5285)
11111
10111
11011
11101
11111
(
00101
01110
11011
01111
10110)
(
11101
00101
11111
10100
10111)


nomove
#FFEED9 #536673
.....
.000.
.010.
.000.
.....

Target
white #231F26
.111.
10001
10101
10001
.111.

Wall
#D9FFDC #7EE58D  #5C8466 #4F5B46
21110
22110
22221
23232
32323

overwall
#D9FFDC #7EE58D  #5C8466 #4F5B46
.....
.....
.....
10000
21100


Playerright
#F2F2AA #E5C17E #4F5B46 #423D39
.000.
11202
11313
11110
.1.1.

playerleft
#F2F2AA #E5C17E #4F5B46 #423D39
.000.
20211
31311
01111
.1.1.


playerani3
#F2F2AA #E5C17E #4F5B46 #423D39
.....
..0..
.1.0.
..1..
.....


playerani
#F2F2AA #E5C17E #4F5B46 #423D39
.....
.0.1.
..1..
.1.1.
.....

playerani2
#F2F2AA #E5C17E #4F5B46 #423D39
.0.0.
0.1.0
.1.1.
1.1.1
.1.1.

Counter
#F2F2AA #E5C17E #CC7A52 #736053
.100.
.210.
.221.
.....
.....

emptycount
black
.....
.000.
.....
.....
.....

emptycount2
#B32D2D
.....
.000.
.....
.....
.....

counterx
TRANSPARENT

Crate
#D9FFF8 #AAE0F2 #7EA1E5 #5C6684
21100
21110
22110
32223
.333.

overcrate
#D9FFF8 #AAE0F2 #7EA1E5 #5C6684
.....
.....
.....
.....
.000.

end
#D9FFF8 #AAE0F2 #7EA1E5 #5C6684
21100
21110
22110
32223
.333.
endx
#D9FFF8 #AAE0F2 #7EA1E5 #5C6684
21100
21110
22110
32223
.333.


spawnCrate
black #AAE0F2 #7EA1E5 #5C6684
20101
21011
20101
32223
.333.

overspawncrate
white #D9FFF8 #AAE0F2 #7EA1E5 #5C6684
.....
.....
.....
.....
.111.

spawn
TRANSPARENT white
.....
.0.0.
..0..
.0.0.
.....

pit
black #231F26 (#E57ED5 #CC5285)
10101
01010
00000
00000
00000

pitfull
black #3B3942 (#E57ED5 #CC5285)
00000
00000
00000
00000
00000



pit1
black #736053 (#E57ED5 #CC5285)
10101
01010
00000
00000
00000

overpitcrate
black #E5C17E #CC7A52 #736053
01210
32121
32212
23221
32332

pitani
black #E5C17E #CC7A52 #736053
.1.1.
3.1.1
.2.1.
3.2.1
.3.3.

pitani2
black #E5C17E #CC7A52 #736053
..1..
.2.1.
3.2.1
.3.2.
..3..

pitani3
black #E5C17E #CC7A52 #736053
.....
..1..
.2.1.
..2..
.....

pitani4
black #E5C17E #CC7A52 #736053
.....
.....
..1..
.....
.....

cloner
#E5C17E #DB7F55 #B32D2D #73342E
.100.
.210.
.221.
.332.
.....

swapcrate
Orange Yellow
00000
0...0
0...0
0...0
00000

swapwall
TRANSPARENT

thefloor
#231F26
00000
00000
00000
00000
00000

thefloorx
#231F26
00000
00000
00000
00000
00000

eend
#231F26
00000
00000
00000
00000
00000
(
checkempty
black
.....
.....
.....
.....
.....

checkblock
black
.....
.....
.....
.....
.....
)

switcrate
TRANSPARENT

switcrate2
TRANSPARENT

pldead
TRANSPARENT

pitdead
TRANSPARENT

arrow
black
.....
.....
.0.0.
.000.
..0..

arrow2
black
.....
.0.0.
.000.
..0..
.....

arrowx
TRANSPARENT

arrowx2
TRANSPARENT

winend
#E5C17E #CC7A52 #736053
1000.
21100
21110
22110
.2221


=======
LEGEND
=======

. = Background
# = Wall
P = Playerright and spawn
* = Crate

O = Target
n = nomove
a = arrow2 and wall
e=end
t = end and target and eend
w=end and winend

c= counter and thefloor
j= counter and counterx and thefloor

-=thefloor
x=thefloorx

'= pit

feel=overwall or overcrate or overspawncrate
pushable=crate or cloner or swapcrate  or switcrate or switcrate2 or spawnCrate or spawnCrate
win=crate or wall


theemx= crate 
player=playerright or playerleft

blocker = wall or crate  or nomove or player or arrow or spawnCrate

arrowk = arrow or arrow2 or arrowx or arrowx2

apit=pit or pitfull or pit1

pitanix=pitani or pitani2 or pitani3 or pitani4

playerx=player or playerani or playerani2 or playerani3
=======
SOUNDS
=======

pushable MOVE 36772507

EndLevel 74089700

player MOVE 68988304
sfx0 52836103
sfx1 45427502

sfx2 29503700
sfx3 81951902

sfx4 52424902

sfx5 69506109
sfx6 34062906
sfx7 83784108
sfx8 94617304
================
COLLISIONLAYERS
================

Background
Target
nomove

pldead
pitdead
spawn

overpitcrate
Player, Wall, pushable,swapwall,thefloor,thefloorx,apit

pitanix
playerani, playerani2, playerani3
emptycount
emptycount2
counterx
counter

arrow, arrow2, arrowx, arrowx2
winend
eend
end, endx
feel


======
RULES
======

[feel]->[]

[pitani4]->[]
[pitani3]->[pitani4]
[pitani2]->[pitani3]
[pitani]->[pitani2]

[playerani2]->[playerright]
[playerani]->[playerani2]
[playerani3]->[playerani]

[> player|pushable] ->[> player| > pushable]

[> pushable|pushable] ->[> pushable| > pushable]

[> pushable|apit]->[> pushable|apit] sfx8

[> player | apit]->[pldead | overpitcrate] sfx4

[> crate|Target]->[> crate|target] sfx2

[> spawnCrate | target]->[> spawnCrate | target] sfx6

[ left Playerright] -> [ left playerleft]
[ right Playerleft] -> [ right playerright]

[endx] ->[thefloor] sfx2
[end | thefloor]-> [endx |thefloor]

late[spawn no playerx]->[spawncrate]

late [spawncrate ] [pldead] [counterx counter] -> [spawn playerani3] [] [emptycount]

late[counter no counterx | emptycount]->[counter counterx | emptycount]



late[overpitcrate blocker no pitdead]->[overpitcrate blocker pitdead]

late[overpitcrate pitdead no blocker no spawn]->[pit pitani] sfx5

late up [spawnCrate| ]->[spawncrate|overspawncrate]

late up [wall| ]-> [wall|overwall]
late up [theemx| ]-> [theemx|overcrate]

(late up [crate2| ]-> [crate2|overcrate2])

late up [end| ]-> [end|overcrate]
late up [endx| ]-> [endx|overcrate]

late up [apit|apit]->[pitfull|apit]

late up [apit|no apit]->[pit|]
late up [apit|overpitcrate]->[pit1|overpitcrate]

late [emptycount] -> [emptycount2]
late [emptycount2][playerx]->[emptycount][playerx]


late[pldead] [emptycount2]->[][emptycount2]sfx7


(late up [apit|overpitcrate2]->[pit2|overpitcrate2])



[]-> again 
(
[arrow]->[arrowx2]
[arrow2]->[arrowx]

[arrowx]->[arrow]
[arrowx2]->[arrow2])
==============
WINCONDITIONS
==============

all Target on crate 

some target
=======
LEVELS
=======

message have a crate on all targets

message level 1 of 7
-------cj
--######-
-##....##
-#..*...#
-#......#
-#''##''#
-#......#
##......#
#P....O.#
#......##
########-

message level 2 of 7
-----cccj
#########
#.......#
#.*.*.*.#
#.......#
#'''''''#
#.......#
#...O.O.#
#.P..O..#
###...###
--#####--

message level 3 of 7
---cccccj
#########
#.#.*O#.#
#.'.'.'.#
#'''''''#
#'''.'''#
#'''''''#
#..'''..#
#.P.....#
#.......#
#########

message level 4 of 7
------ccj
#########
#.#...#.#
#..*.*..#
#..*#*..#
#'''''''#
#.......#
#...OO..#
#.P.OO..#
##.....##
-#######-


message level 5 of 7
---cccccj
#########
#...O...#
#..O.O..#
#'''''''#
#.'''''.#
#.'''''.#
#.......#
#.**.P*.#
#.......#
#########


message level 6 of 7
--ccccccj
#########
#...#...#
#.*.#.O.#
#.'.'.'.#
#'.'P'.'#
#.'.'.'.#
#...#...#
#.O.#.*.#
#.......#
#########

message level 7 of 7
----ccccj
#########
#.......#
#..*'*..#
#.'.P.'.#
#..*.*..#
#.'''''.#
#.'...'.#
#.OO'OO.#
#.......#
#########

(------ccj
#########
#.O'O'O.#
#..'''..#
#.'''''.#
#..'''..#
#.......#
#...P...#
#.*.*.*.#
#.......#
#########)

(-----cccj
#########
#..OOO..#
#'''''''#
#.......#
#...P...#
#'''''''#
#.......#
#..***..#
#..###..#
#########)


xxxxxxxxxxxxxx
-eeeeeeeeeeee-
eeeeeeeeeeeeee
eeeeeeeeeeeeee
wewewewwweweew
wewewetweewwew
weweweeweeweww
eweweewwweweew
eeeeeeeeeeeeee
eeeeeeeeeeeeee
-eeeeeeeeeeee-


