title Manic Ammo
author David Eastman
homepage @eastmad

========
OBJECTS
========

Background 
gray  

Target 
darkgray gray lightgray white
33333
31112
31002
31002
32222

Wall 
BROWN

Boom
Red YELLOW orange    
.101.
10001
00200
10001
.101.


Player 
PINK YELLOW BLACK    
.222.
.000.
22122
.222.
.2.2.


CrateW 
Brown DarkBrown lightbrown
11111
12001
11111
12001
11111

CrateN
Brown DarkBrown lightbrown
11111
12121
10101
10101
11111

CrateMineN
Brown DarkBrown lightbrown darkblue
11111
12121
10101
10301
11111

CrateGunN
Brown DarkBrown lightbrown darkred
11111
12121
10101
10301
11111

CrateGunS
Brown DarkBrown lightbrown darkred
11111
12321
10101
10101
11111


CrateS
Brown DarkBrown lightbrown
11111
10101
10101
12121
11111

CrateE
Brown DarkBrown lightbrown
11111
10021
11111
10021
11111


Shell
yellow orange
..0..
.000.
.000.
.000.
.101.


Bang
Yellow LightRed
.101.
10001
00000
10001
.101.

GunN
red lightred
..0..
..0..
.101.
00000
.000.

GunW
red lightred
...0.
..100
00000
..100
...0.

GunS
red lightred
.000.
00000
.101.
..0..
..0..

GunE
red lightred
.0...
001..
00000
001..
.0...

InertMine
darkblue blue lightblue
.....
.101.
.020.
.101.
.....

ActiveMine
darkred red lightred
.....
.101.
.020.
.101.
.....

Squawk
lightblue blue
....0
.0000
.0000
.11.0
1111.

SquawkBang
orange lightblue
....0
.0000
.0000
.11.0
1111.

Droid
black green
..0..
.000.
00100
.000.
..0..


=======
LEGEND
=======

. = Background
# = Wall
P = Player
N = CrateN
E = CrateE
W = CrateW
S = CrateS
O = Target
+ = Shell
^ = GunN
< = GunW
> = GunE
˅ = GunS
M = InertMine
A = ActiveMine
B = Boom
% = CrateGunN
& = CrateMineN
@ = CrateGunS
X = Squawk
D = Droid

=======
SOUNDS
=======

SFX1 55891909
SFX2 5736502
SFX4 6922102

Shell move 61960307
InertMine move 61960307
Droid move 81713505
EndLevel 8341708
Shell create 91688700
GunN create 91688700
GunS create 91688700
GunW create 91688700
InertMine create 91688700
ActiveMine create 93182703

================
COLLISIONLAYERS
================

Background
Target
Player, Wall, CrateN, CrateE, CrateW, CrateS, Shell, GunN, GunW, GunE, GunS, Bang, InertMine, ActiveMine, Boom, CrateMineN, CrateGunN, CrateGunS, Squawk, Droid, SquawkBang

======
RULES     
======     
 
 
[Bang] -> [background]
[boom] -> restart
[> player][Droid] -> [> player][> Droid]
[ >  Player | Shell ] -> [  >  Player | > Shell  ] 
[ >  Droid | Shell ] -> [  >  Droid | > Shell  ]
[ >  Player | InertMine ] -> [  >  Player | > InertMine  ] 
[Action Player|InertMine] -> [Action Player|ActiveMine]
[> Droid|InertMine] -> [Droid|ActiveMine]
[> Player | ActiveMine] -> [Player | boom ]
[> Droid | ActiveMine] -> [Droid | boom ]
[> shell | ActiveMine] -> [boom | boom ]
 
[Action Player|Squawk] -> [Action Player|SquawkBang]
[> Droid|Squawk] -> [Droid |SquawkBang]

[SquawkBang][CrateMineN] -> [SquawkBang][ActiveMine] 
[SquawkBang][CrateGunN] -> [SquawkBang][GunN]
[SquawkBang][CrateGunS] -> [SquawkBang][GunS]
[SquawkBang][CrateN] -> [SquawkBang][Shell] 
[SquawkBang][CrateS] -> [SquawkBang][Shell]
[SquawkBang][CrateE] -> [SquawkBang][Shell]
[SquawkBang][CrateW] -> [SquawkBang][Shell]
[SquawkBang] -> [] SFX1

DOWN [ Action Player |CrateN] -> [Action Player | Shell]
UP [Action Player | CrateS] -> [Action Player | Shell]
LEFT [Action Player | CrateE] -> [Action Player | Shell]
RIGHT [Action Player | CrateW] -> [Action Player | Shell] 
DOWN [Action Player | CrateGunN] -> [Action Player | GunN]
UP [Action Player | CrateGunS] -> [Action Player | GunS]
DOWN [Action Player | CrateMineN] -> [Action Player | ActiveMine]

UP [Action Player | GunN| No Bang ] -> [Player | GunN | Bang ] SFX4
LEFT [Action Player | GunW | No Bang] -> [Player | GunW | Bang ] SFX4
DOWN [Action Player | GunS| No Bang ] -> [Player | GunS | Bang ] SFX4
RIGHT [Action Player | GunE | No Bang] -> [Player | GunE | Bang ] SFX4

UP [ > Droid | GunN| No Bang ] -> [Droid | GunN | Bang ] SFX4
LEFT [ > Droid | GunW | No Bang] -> [Droid | GunW | Bang ] SFX4
DOWN [> Droid | GunS| No Bang ] -> [Droid | GunS | Bang ] SFX4
RIGHT [> Droid | GunE | No Bang] -> [Droid | GunE | Bang ] SFX4
[bang|shell] -> [bang|bang ]
[boom|no player] -> [boom|boom] SFX2


==============
WINCONDITIONS
==============

All Player on Target

=======     
LEVELS
=======



MESSAGE Due to a clerical error, You are trapped in a bunker

########
#.....P#
#......#
#......#
#......#
#O.....#
########

MESSAGE A bunker with several levels, full of crates and munitions

########
#.....O#
#..+...#
#......#
#..N...#
#P.....#
########

MESSAGE Crates open from one side

########
#...+.P#
#....+.#
#..++..#
#++..++#
#.ON...#
########

MESSAGE But shells are volatile
MESSAGE Try firing the gun 

#########
#..+.+.O#
#..N+...#
#....S..#
#...^...#
#.P.....#
#########

MESSAGE Chain reaction

#########
#+.+O+.P#
#+.++...#
#.+.+.N.#
#+......#
#E+++.<.#
#########

MESSAGE Inert mines, active mines

#########
#+.+P+..#
#.......#
#.......#
#SSSSM..#
#.O.E...#
#########

Message Crates can have any munitions in them

#########
#.......#
#.&+..+.#
#.+O&.+.#
#.+++%..#
#.P.S...#
#########


MESSAGE There seems to be another way to open crates

#########
#.X.....#
#.......#
#..P....#
#....NNN#
#.>..SON#
#########


MESSAGE Hey, it's a friendly worker droid!

#########
#.D...PN#
#..+...N#
#A.+....#
#.NN.O..#
#..+....#
#########


MESSAGE Now this is where the main bunker levels begin.

###########
#O+N..+.W.#
#SN&..+.NX#
#.DN.+.+..#
#%.NWP.NS+#
#...+N....#
###########


MESSAGE This doesn't look safe

###########
#P..&&&&&&#
#DX.N....&#
#...&&&&&&#
#.N.N...O.#
#&&&&&&&&&#
###########


MESSAGE Carefully packed

###########
#PESW.WDW.#
#NW..&N@.N#
#.N%NWN.X.#
#N...NNNNN#
#N.NNNNNON#
###########

MESSAGE Symbiosis

###########
#P.NNN.DN.#
#MM>.+++N.#
#..N.NN+..#
#++N++....#
#++...<.O.#
###########

MESSAGE Inert Mine field

###########
#.P..M.M..#
#.MMM.M.MM#
#..M..MNM.#
#MM.MM.MOS#
#.M..MD...#
###########

MESSAGE Last level

###########
#..+..P.+.#
#.N..@.N..#
#+.&..E.&.#
#++..S.SSS#
#.X+&..NO.#
###########

MESSAGE Congratulations! Now you can return to fighting on the front line.