title Hue change
author Rosden Shadow [Mark Signorelli]
homepage rosden.itch.io

background_color #3B3942

text_color #D9FFDC

again_interval 0.1

run_rules_on_level_start
========
OBJECTS
========

Background
#3B3942 #52465B
00000
01100
00000
00110
00000

Target
DarkBlue
.....
.000.
.0.0.
.000.
.....

Wall
#FFD9FC #E0AAF2 #705C84 #52465B #3B3942
21110
21110
21110
22221
33332

overWall
#FFD9FC #E0AAF2 #705C84 #52465B #3B3942
.....
.....
.....
.....
10000

playerright
#D9FFDC #7EE58D #5C8466
.222.
.200.
.1110
.111.
.1.1.

playerleft
#D9FFDC #7EE58D #5C8466
.222.
.002.
0111.
.111.
.1.1.

playerdown
#D9FFDC #7EE58D #5C8466
.222.
.000.
01110
.111.
.1.1.

playerup
#D9FFDC #7EE58D #5C8466
.222.
.222.
01110
.111.
.1.1.
(
Player
#CC7A52 #73342E #E5C17E
.222.
.000.
01110
.111.
.1.1.
)

Crate
#D9FFF8 #AAE0F2  #7EA1E5 #394239 #E5C17E #CC7A52 #736053
21100
21110
22110
32223
.333.

(cratem
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.0.0.
2.1.0
.1.1.
2.1.0
.2.2.
cratem3
#D9FFF8 #AAE0F2  #7EA1E5 #394239
..0..
.1.0.
2.1.0
.2.1.
..2..


cratem2
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.....
..0..
.2.0.
..2..
.....
cratem1
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.....
.....
..0..
.....
.....)

cratem
#D9FFF8 #AAE0F2  #7EA1E5 #394239
2.1.0
.1.1.
2.1.0
.2.2.
.....
cratem3
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.1.0.
2.1.0
.2.1.
..2..
.....
cratem2
#D9FFF8 #AAE0F2  #7EA1E5 #394239
..0..
.2.0.
..2..
.....
.....
cratem1
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.....
..0..
.....
.....
.....
overcratem
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.....
.....
.....
.....
.0.0.

overcratem3
#D9FFF8 #AAE0F2  #7EA1E5 #394239
.....
.....
.....
.....
..0..

(Crate
#D9FFF8 #AAE0F2  #7EA1E5 #394239 #E5C17E #CC7A52 #736053
21100
54110
55440
65556
.666.)

crate2
#F2F2AA #E5C17E #CC7A52 #736053
21100
21110
22110
32223
.333.
(
crate2m
#F2F2AA #E5C17E #CC7A52 #736053
.0.0.
2.1.0
.1.1.
2.1.0
.2.2.
crate2m3
#F2F2AA #E5C17E #CC7A52 #736053
..0..
.1.0.
2.1.0
.2.1.
..2..
crate2m2
#F2F2AA #E5C17E #CC7A52 #736053
.....
..0..
.2.0.
..2..
.....
crate2m1
#F2F2AA #E5C17E #CC7A52 #736053
.....
.....
..0..
.....
.....)

crate2m
#F2F2AA #E5C17E #CC7A52 #736053
2.1.0
.1.1.
2.1.0
.2.2.
.....
crate2m3
#F2F2AA #E5C17E #CC7A52 #736053
.1.0.
2.1.0
.2.1.
..2..
.....
crate2m2
#F2F2AA #E5C17E #CC7A52 #736053
..0..
.2.0.
..2..
.....
.....
crate2m1
#F2F2AA #E5C17E #CC7A52 #736053
.....
..0..
.....
.....
.....
overcrate2m
#F2F2AA #E5C17E #CC7A52 #736053
.....
.....
.....
.....
.0.0.

overcrate2m3
#F2F2AA #E5C17E #CC7A52 #736053
.....
.....
.....
.....
..0..

overcrate
#D9FFDC
.....
.....
.....
.....
.000.

overcrate2
#F2F2AA #E5C17E #CC7A52 #736053
.....
.....
.....
.....
.000.


thefloor
#3B3942
00000
00000
00000
00000
00000

(------------Start score----------)

a1
white
..0..
.00..
..0..
..0..
.000.

a2
white
.00..
...0.
..0..
.0...
.000.

a3
white
.00..
...0.
.00..
...0.
.00..

a4
white
.0...
.0.0.
.000.
...0.
...0.

a5
white
.000.
.0...
.00..
...0.
.00..

a6
white
..00.
.0...
.000.
.0.0.
.000.

a7
white
.000.
...0.
...0.
...0.
...0.

a8
white
.000.
.0.0.
.000.
.0.0.
.000.

a9
white
..00.
.0.0.
.000.
...0.
...0.

a0
white
..00.
.0.0.
.0.0.
.0.0.
.00..

as
white
.000.
.0...
.000.
...0.
.000.

ac
white
.000.
.0...
.0...
.0...
.000.

ao
white
.000.
.0.0.
.0.0.
.0.0.
.000.

ar
white
.000.
.0.0.
.000.
.00..
.0.0.

ae
white
.000.
.0...
.000.
.0...
.000.

an
white
.....
..0..
.....
..0..
.....

sscore
black
.....
.....
.....
.....
.....

nscore
black
.....
.....
.....
.....
.....


addscore
black
.....
.....
.....
.....
.....

nextscore
black
.....
.....
.....
.....
.....
nummove
black
.....
.....
.....
.....
.....
nummax
black
.....
.....
.....
.....
.....

scoreendpoint
black
.....
.....
.....
.....
.....

(------------End score----------)

onthep
black
.....
.....
.....
.....
.....

wait
black
.....
.....
.....
.....
.....

wait1
black
.....
.....
.....
.....
.....

wait2
black
.....
.....
.....
.....
.....

wait3
black
.....
.....
.....
.....
.....

spawner1
black
.....
.....
.....
.....
.....

spawner2
black
.....
.....
.....
.....
.....

asco
black
.....
.....
.....
.....
.....
blackdot
black
.....
..0..
.....
.....
.....

=======
LEGEND
=======

. = Background
# = Wall
P = Playerdown
O = Target
- = thefloor
1= as and thefloor
2=ac and thefloor
3 = ao and thefloor
4=ar and thefloor
5=ae and thefloor
6=an and thefloor
7=sscore and thefloor and a0
z=scoreendpoint and thefloor
j=spawner1 and Crate and asco and blackdot
k=spawner2 and crate2 and asco and blackdot

player = playerright or playerleft or playerdown or playerup
w =wait and thefloor
numbers = a1 or a2 or a3 or a4 or a5 or a6 or a7 or a8 or a9 or a0
letters = as or ac or ao or ar or ae or an 

blocker = player or wall or Crate or crate2
waitx = wait1 or wait or wait2 or wait3

push = Crate or crate2
feel=overcrate or overcrate2 or overWall

them=cratem or cratem3 or cratem2 or cratem1 or crate2m or crate2m3 or crate2m2 or crate2m1
themover = overcratem or overcratem3 or overcrate2m or overcrate2m3
=======
SOUNDS
=======

Crate MOVE 36772507

sfx0 97777702

player move 48296904

sfx1 53886700
================
COLLISIONLAYERS
================

Background
Target
onthep
asco
thefloor
spawner1
spawner2
Player, Wall, Crate,crate2
waitx

(score)
numbers
letters
sscore
nscore
addscore
nextscore
nummove
nummax
scoreendpoint
(endscore)

blackdot
them
feel
themover


======
RULES
======

[feel]->[]
[themover]->[]

[cratem]->[Crate]
[cratem3]->[cratem]
[cratem2]->[cratem3]
[cratem1]->[cratem2]

[crate2m]->[Crate2]
[crate2m3]->[crate2m]
[crate2m2]->[crate2m3]
[crate2m1]->[crate2m2]

[player]->[player onthep]
[> player|push]->[> player | > push]
([> Crate|crate]->[|crate2] sfx0)

[ Crate |no blocker no them |crate]->[crate crate2m1|cratem1 | crate crate2m1] sfx0
[ Crate2|no blocker no them |crate2]->[crate2 cratem1|crate2m1 | crate2 cratem1] sfx0
(
[ Crate|crate2|crate]->[crate2| |crate2] sfx0
[ Crate2|crate|crate2]->[crate| |crate] sfx0)


(---score---)
(late [onthep no player] [sscore]->[onthep] [addscore sscore])
late [player asco] [sscore]->[player] [addscore sscore] sfx1
(numbers up)
late [addscore a0]->[a1]
late [addscore a1]->[a2]
late[addscore a2]->[a3]
late[addscore a3]->[a4]
late[addscore a4]->[a5]
late[addscore a5]->[a6]
late[addscore a6]->[a7]
late[addscore a7]->[a8]
late[addscore a8]->[a9]
late[addscore a9]->[a0 nextscore]
left[ nextscore | nscore]->[ | addscore nscore]
(moving numbers across)
late left[ nextscore | no nscore]->[ a1 | nummove]
late[nummove] [sscore]->[nummove] [nummove sscore]
late right [nummove sscore| thefloor]->[ nscore | sscore thefloor a0]
late right [nummove sscore scoreendpoint]->[nummax] 
late [nummax][numbers]->[nummax][a9]
late [nummove]->[]
[]->again
(---score done---)

late [spawner1 no blocker]->[spawner1 Crate asco]
late [spawner2 no blocker]->[spawner2 Crate2 asco]

(late [ left Playerright] -> [ left playerleft]
late [ right Playerleft] -> [ right playerright])

(late [onthep no player][wait3]->[onthep crate][wait]
late [onthep no player][wait2]->[onthep ][wait3])

(
late [onthep no player][wait2]->[onthep crate][wait]
late [onthep no player][wait1]->[onthep][wait2]
late [onthep no player][wait]->[onthep][wait1])
late [onthep]->[]



late up[crate|]->[crate|overcrate]
late up[crate2|]->[crate2|overcrate2]
late up[wall|]->[wall|overwall]
late up[cratem|]->[cratem|overcratem]
late up[cratem3|]->[cratem3|overcratem3]
late up[crate2m|]->[crate2m|overcrate2m]
late up[crate2m3|]->[crate2m3|overcrate2m3]

[right player]->[right playerright]
[left player]->[left playerleft]
[up player]->[up playerup]
[down player]->[down playerdown]
==============
WINCONDITIONS
==============

All player on target

=======
LEVELS
=======

message THE RULES: a block spawns inbetween 2 blocks of the same colour. both those blocks then switch colour
message GOAL: touch the black dots as much as possible and get the highest score you can
1234567-z
w--------
#########
#.......#
#.......#
#..j.k..#
#...p...#
#.......#
#########

(best score from me is 17)



