title swap
author Rosden Shadow [Mark Signorelli]
homepage rosden.itch.io

noaction
run_rules_on_level_Start

background_color #465B4D

text_color #E5C17E 

again_interval 0.2
========
OBJECTS
========

Background
#567353 #465B4D (#E57ED5 #CC5285)
11111
10101
11111
10101
11111
(
00101
01110
11011
01111
10110)
(
11101
00101
11111
10100
10111)


nomove
#FFEED9 #536673
.....
.000.
.010.
.000.
.....

Target
#BCF2AA
.....
.000.
.0.0.
.000.
.....

Wall
#CC7A52 #B32D2D  #73342E #4D3C2E #E5C17E 
21110
21110
22211
23232
32323

overwall
#CC7A52 #B32D2D  #73342E #4D3C2E #E5C17E 
.....
.....
.....
10004
11110


Playerright
#D9FFDC #7EE58D #B32D2D  #73342E #7F7CA1 #705C84
.000.
11202
11313
11110
.1.1.

playerleft
#D9FFDC #7EE58D #B32D2D  #73342E #7F7CA1 #705C84
.000.
20211
31311
01111
.1.1.

Crate
#F2F2AA #E5C17E #CC7A52 #736053
21100
21110
22110
32223
.333.

overcrate
#F2F2AA #E5C17E #CC7A52 #736053
.....
.....
.....
.....
.000.

end
#F2F2AA #E5C17E #CC7A52 #736053
21100
21110
22110
32223
.333.
endx
#F2F2AA #E5C17E #CC7A52 #736053
21100
21110
22110
32223
.333.



cloner
#E5C17E #DB7F55 #B32D2D #73342E
.100.
.210.
.221.
.332.
.....

swapcrate
Orange Yellow
00000
0...0
0...0
0...0
00000

swapwall
black
.....
.....
.....
.....
.....

thefloor
#465B4D
00000
00000
00000
00000
00000

thefloorx
#465B4D
00000
00000
00000
00000
00000

eend
#465B4D
00000
00000
00000
00000
00000
(
checkempty
black
.....
.....
.....
.....
.....

checkblock
black
.....
.....
.....
.....
.....
)

switcrate
black
.....
.....
.....
.....
.....

switcrate2
black
.....
.....
.....
.....
.....

arrow
black
.....
.....
.0.0.
.000.
..0..

arrow2
black
.....
.0.0.
.000.
..0..
.....

arrowx
black
.....
.....
.....
.....
.....

arrowx2
black
.....
.....
.....
.....
.....

winend
 #CC7A52 #B32D2D  #73342E #E5C17E
1003.
21103
21110
22110
.2221


=======
LEGEND
=======

. = Background
# = Wall
P = Playerright
* = Crate

O = Target
n = nomove
a = arrow2 and wall
e=end
t = end and target and eend
w=end and winend

c=cloner
-=thefloor
x=thefloorx

feel=overwall or overcrate 
pushable=crate or cloner or swapcrate  or switcrate or switcrate2
win=crate or wall


theemx= crate 
player=playerright or playerleft

blocker = wall or crate  or nomove or player or arrow

arrowk = arrow or arrow2 or arrowx or arrowx2
=======
SOUNDS
=======

pushable MOVE 36772507

EndLevel 74089700

player MOVE 68988304
sfx0 52836103
sfx1 45427502

sfx2 48550305(29503700)
sfx3 81951902

sfx4 10427701
================
COLLISIONLAYERS
================

Background
Target
nomove
Player, Wall, pushable,swapwall,thefloor,thefloorx

arrow, arrow2, arrowx, arrowx2
winend
eend
end, endx
feel


======
RULES
======

[feel]->[]

[> player target|crate|crate|crate|crate|crate|crate]->[crate  target|crate|crate|crate|crate|crate|player] sfx2 
[> player target|crate|crate|crate|crate|crate]->[crate  target|crate|crate|crate|crate|player] sfx2 
[> player target|crate|crate|crate|crate]->[crate target|crate|crate|crate|player] sfx2 
[> player target|crate|crate|crate]->[crate target|crate|crate|player] sfx2 
[> player target|crate|crate]->[crate target|crate|player] sfx2
[> player target|crate]->[crate target|player] sfx2

[> player|crate|crate|crate|crate|crate|crate]->[crate|crate|crate|crate|crate|crate|player] sfx4 
[> player|crate|crate|crate|crate|crate]->[crate|crate|crate|crate|crate|player] sfx4 
[> player|crate|crate|crate|crate]->[crate|crate|crate|crate|player] sfx4 
[> player|crate|crate|crate]->[crate|crate|crate|player] sfx4 
[> player|crate|crate]->[crate|crate|player] sfx4 
[> player|crate]->[crate|player] sfx4 

[> crate|Target]->[> crate|target] sfx2

[ left Playerright] -> [ left playerleft]
[ right Playerleft] -> [ right playerright]

[endx] ->[thefloor] sfx2
[end | thefloor]-> [endx |thefloor]


late up [wall| ]-> [wall|overwall]
late up [theemx| ]-> [theemx|overcrate]

(late up [crate2| ]-> [crate2|overcrate2])

late up [end| ]-> [end|overcrate]
late up [endx| ]-> [endx|overcrate]

[action player eend|]->[action player eend |crate Target]



[]-> again 
(
[arrow]->[arrowx2]
[arrow2]->[arrowx]

[arrowx]->[arrow]
[arrowx2]->[arrow2])
==============
WINCONDITIONS
==============

all Target on crate 

some target

=======
LEVELS
=======




message have a crate on all targets

message level 1 of 6
---------
-#######-
##.....##
#....O..#
#.......#
#.......#
#..*....#
#....P..#
##.....##
-#######-

message level 2 of 6
---------
---------
---------
-######--
-#OP.O#--
-#.**.#--
-#.**.#--
-#O..O#--
-######--
---------


message level 3 of 6
---------
-.#####.-
-##...##-
##O.O.O##
#..#.#..#
#..#.#..#
#..***..#
#.......#
##..P..##
-#######-


message level 4 of 6
---------
---------
-#######-
-#*.P.*#-
-#.#O#.#-
-#.OOO.#-
-#.#O#.#-
-#*.*.*#-
-#######-
---------


message level 5 of 6
---------
-#######-
-#*****#-
##*****##
#*******#
#**O****#
#*******#
#*****.*#
##**P**##
-#######-


message level 6 of 6
---------
---------
--####---
-##..####
-#***OOO#
-#***OOO#
-#***OOO#
-##.P####
--####---
---------



xxxxxxxxxxxxxx
-eeeeeeeeeeee-
eeeeeeeeeeeeee
eeeeeeeeeeeeee
wewewewwweweew
wewewetweewwew
weweweeweeweww
eweweewwweweew
eeeeeeeeeeeeee
eeeeeeeeeeeeee
-eeeeeeeeeeee-



