title triple match
author Rosden Shadow [Mark Signorelli]
homepage rosden.itch.io

noaction
run_rules_on_level_Start

background_color #3B3942

text_color #FFFFFF

again_interval 0.2
========
OBJECTS
========

Background
#705C84 #3B3942 (#E57ED5 #CC5285)
11111
11011
10101
11011
11111
(
00101
01110
11011
01111
10110)
(
11101
00101
11111
10100
10111)


nomove
#FFEED9 #536673
.....
.000.
.010.
.000.
.....

Target
#FFD9E0 #423D39
.....
.010.
.0.1.
.000.
.....

Wall
#FFFFFF #CCCCCC #999999 #666666
21110
22110
22221
23232
32323

overwall
#FFFFFF #CCCCCC #999999 #666666
.....
.....
.....
10000
21100


Playerright
#FFFFFF #CCCCCC #666666 #333333
.000.
11202
11313
11110
.1.1.

playerleft
#FFFFFF #CCCCCC #666666 #333333
.000.
20211
31311
01111
.1.1.

Playerrightred
#E5C17E #CC7A52 #666666 #333333 #B32D2D
.000.
11202
11313
11110
.1.1.

playerleftred
#E5C17E #CC7A52 #666666 #333333 #B32D2D
.000.
20211
31311
01111
.1.1.

Playerrightblue
#AAE0F2 #7EA1E5 #666666 #333333
.000.
11202
11313
11110
.1.1.

playerleftblue
#AAE0F2 #7EA1E5 #666666 #333333
.000.
20211
31311
01111
.1.1.

Playerrightgreen
#D9FFDC #7EE58D #666666 #333333
.000.
11202
11313
11110
.1.1.

playerleftgreen
#D9FFDC #7EE58D #666666 #333333
.000.
20211
31311
01111
.1.1.


Playerrightyellow
#F2F2AA #E5C17E #666666 #333333 
.000.
11202
11313
11110
.1.1.

playerleftyellow
#F2F2AA #E5C17E #666666 #333333 
.000.
20211
31311
01111
.1.1.


Crate
#E5C17E #CC7A52 #B32D2D #73342E
21100
21110
22110
32223
.333.

overcrate
#E5C17E #CC7A52 #B32D2D #73342E
.....
.....
.....
.....
.000.

Cratedead
#E5C17E #CC7A52 #B32D2D #73342E
..0..
.1.0.
2.1.0
.2.1.
..2..
(
1.0.0
.1.1.
2.1.0
.1.1.
2.2.1)
(
.0.0.
2.1.0
.1.1.
2.1.0
.2.2.)

Crateg
#B19F7E #A57C68 #985656 #795956
21100
21110
22110
32223
.333.

overcrateg
#B19F7E #A57C68 #985656 #795956
.....
.....
.....
.....
.000.


Crate2
#AAE0F2 #7EA1E5 #5C6684 #46495B
21100
21110
22110
32223
.333.

overcrate2
#AAE0F2 #7EA1E5 #5C6684 #46495B
.....
.....
.....
.....
.000.

Crate2dead
#AAE0F2 #7EA1E5 #5C6684 #46495B
..0..
.1.0.
2.1.0
.2.1.
..2..

Crate2g
#94AFB8 #7E8FB1 #6D7281 #62646D
21100
21110
22110
32223
.333.

overcrate2g
#94AFB8 #7E8FB1 #6D7281 #62646D
.....
.....
.....
.....
.000.

Crate3
#D9FFDC #7EE58D #5C8466 #4F5B46
21100
21110
22110
32223
.333.

overcrate3
#D9FFDC #7EE58D #5C8466 #4F5B46
.....
.....
.....
.....
.000.

Crate3dead
#D9FFDC #7EE58D #5C8466 #4F5B46
..0..
.1.0.
2.1.0
.2.1.
..2..

Crate3g
#ABBEAD #7EB185 #6D8172 #676D62
21100
21110
22110
32223
.333.

overcrate3g
#ABBEAD #7EB185 #6D8172 #676D62
.....
.....
.....
.....
.000.


Crate4
#F2F2AA #E5C17E #847A5C #5B5746
21100
21110
22110
32223
.333.

overcrate4
#F2F2AA #E5C17E #847A5C #5B5746
.....
.....
.....
.....
.000.

Crate4dead
#F2F2AA #E5C17E #847A5C #5B5746
..0..
.1.0.
2.1.0
.2.1.
..2..

Crate4g
#B8B894 #B19F7E #817C6D #6D6B62
21100
21110
22110
32223
.333.

overcrate4g
#B8B894 #B19F7E #817C6D #6D6B62
.....
.....
.....
.....
.000.


end
#AAE0F2 #7EA1E5 #5C6684 #46495B
21100
21110
22110
32223
.333.
endx
#AAE0F2 #7EA1E5 #5C6684 #46495B
21100
21110
22110
32223
.333.



cloner
#E5C17E #DB7F55 #B32D2D #73342E
.100.
.210.
.221.
.332.
.....

swapcrate
Orange Yellow
00000
0...0
0...0
0...0
00000

swapwall
black
.....
.....
.....
.....
.....

thefloor
#3B3942
00000
00000
00000
00000
00000

thefloorx
#3B3942
00000
00000
00000
00000
00000

eend
#3B3942
00000
00000
00000
00000
00000
(
checkempty
black
.....
.....
.....
.....
.....

checkblock
black
.....
.....
.....
.....
.....
)

switcrate
black
.....
.....
.....
.....
.....

switcrate2
black
.....
.....
.....
.....
.....

arrow
black
.....
.....
.0.0.
.000.
..0..

arrow2
black
.....
.0.0.
.000.
..0..
.....

arrowx
black
.....
.....
.....
.....
.....

arrowx2
black
.....
.....
.....
.....
.....

reddead
black
.....
.....
.....
.....
.....

bluedead
black
.....
.....
.....
.....
.....


greendead
black
.....
.....
.....
.....
.....

yellowdead
black
.....
.....
.....
.....
.....

desu
black
.....
.....
.....
.....
.....

desd
black
.....
.....
.....
.....
.....

desl
black
.....
.....
.....
.....
.....

desr
black
.....
.....
.....
.....
.....

may
black
.....
.....
.....
.....
.....

winend
#D9FFDC #7EE58D #5C8466 #4F5B46
1000.
21100
21110
22110
.2221


=======
LEGEND
=======

. = Background
# = Wall
P = Playerright
1 = Crate
2 = crate2
3 = crate3
4 = crate4
O = Target
n = nomove
a = arrow2 and wall
e=end 
t = end and target and eend 
w=end and winend

c=cloner
-=thefloor
x=thefloorx

feel=overwall or overcrate or overcrate2 or overcrate3 or overcrate4 or overcrateg or overcrate2g or overcrate3g or overcrate4g
ghost=Crateg or Crate2g or crate3g or crate4g

dead=Cratedead or Crate2dead or Crate3dead or Crate4dead
pushable=crate or cloner or swapcrate  or switcrate or switcrate2 or Crate2 or crate3 or crate4
win=crate or wall

remove = ghost or pushable

theemx= crate 
theright=playerrightred or playerright or Playerrightblue or Playerrightgreen or Playerrightyellow
theleft= playerleftred or playerleft or playerleftblue or playerleftgreen or playerleftyellow
player=theright or theleft

pred=playerrightred or playerleftred
pblue=playerrightblue or playerleftblue
pgreen=playerrightgreen or playerleftgreen
pyellow=playerrightyellow or playerleftyellow

blocker = wall or crate  or nomove or player or arrow

arrowk = arrow or arrow2 or arrowx or arrowx2
des=desu or desl or desr or desd
=======
SOUNDS
=======

pushable MOVE 36772507

EndLevel 74089700

player MOVE 68988304
sfx0 52836103
sfx1 45427502

sfx2 29503700
sfx3 81951902

sfx4 89849702

sfx5 48315304 
================
COLLISIONLAYERS
================

Background
Target
reddead,bluedead,greendead,yellowdead
nomove
may
desu
desd
desl
desr
ghost
Player, Wall, pushable,swapwall,thefloor,thefloorx

dead
arrow, arrow2, arrowx, arrowx2
winend
eend
end, endx
feel


======
RULES
======

[feel]->[]

[> player|pushable]->[> player|> pushable]


[> pushable|ghost]->[pushable|ghost] sfx5
(red)
late left [crate| crate] -> [crate|crate desl]
late right [crate| crate] -> [crate|crate desr]
late up [crate| crate] -> [crate|crate desu]
late down [crate| crate] -> [crate|crate desd]
(blue)
late left [crate2| crate2] -> [crate2|crate2 desl]
late right [crate2| crate2] -> [crate2|crate2 desr]
late up [crate2| crate2] -> [crate2|crate2 desu]
late down [crate2| crate2] -> [crate2|crate2 desd]
(green)
late left [crate3| crate3] -> [crate3|crate3 desl]
late right [crate3| crate3] -> [crate3|crate3 desr]
late up [crate3| crate3] -> [crate3|crate3 desu]
late down [crate3| crate3] -> [crate3|crate3 desd]
(yellow)
late left [crate4| crate4] -> [crate4|crate4 desl]
late right [crate4| crate4] -> [crate4|crate4 desr]
late up [crate4| crate4] -> [crate4|crate4 desu]
late down [crate4| crate4] -> [crate4|crate4 desd]

(all)
late [pushable des no may]->[pushable may]
(red)
late [crate des may]->[Crate reddead]  sfx4
(blue)
late [crate2 des may]->[Crate2 bluedead]  sfx4
(green)
late [crate3 des may]->[Crate3 greendead]  sfx4
(yellow)
late [crate4 des may]->[Crate4 yellowdead]  sfx4

(all)
late [may]->[]
late [des]->[]

(red)
late [Cratedead]->[]
late[crate reddead|crate]->[Crate reddead|Crate reddead]
late[crate reddead]->[Cratedead]
(blue)
late [Crate2dead]->[]
late[crate2 bluedead|crate2]->[Crate2 bluedead|Crate2 bluedead]
late[crate2 bluedead]->[Crate2dead]
(green)
late [Crate3dead]->[]
late[crate3 greendead|crate3]->[Crate3 greendead|Crate3 greendead]
late[crate3 greendead]->[Crate3dead]
(yellow)
late [Crate4dead]->[]
late[crate4 yellowdead|crate4]->[Crate4 yellowdead|Crate4 yellowdead]
late[crate4 yellowdead]->[Crate4dead]


(red)
late[theright|Cratedead]->[Playerrightred|cratedead]
late[theleft|Cratedead]->[Playerleftred|cratedead]
(blue)
late[theright|Crate2dead]->[Playerrightblue|crate2dead]
late[theleft|Crate2dead]->[Playerleftblue|crate2dead]
(green)
late[theright|Crate3dead]->[Playerrightgreen|crate3dead]
late[theleft|Crate3dead]->[Playerleftgreen|crate3dead]
(yellow)
late[theright|Crate4dead]->[Playerrightyellow|crate4dead]
late[theleft|Crate4dead]->[playerleftyellow|crate4dead]

(red)
late[no pred][Crateg no pred]->[no pred][Crate]
late[pred][Crate]->[pred][Crateg]
(blue)
late[no pblue][Crate2g no pblue]->[no pblue][Crate2]
late[pblue][Crate2]->[pblue][Crate2g]
(green)
late[no pgreen][Crate3g no pgreen]->[no pgreen][Crate3]
late[pgreen][Crate3]->[pgreen][Crate3g]
(yellow)
late[no pyellow][Crate4g no pyellow]->[no pyellow][Crate4]
late[pyellow][Crate4]->[pyellow][Crate4g]


[ left Playerrightred] -> [ left playerleftred]
[ right Playerleftred] -> [ right playerrightred]
[ left Playerrightblue] -> [ left playerleftblue]
[ right playerleftblue] -> [ right Playerrightblue]
[ left Playerrightgreen] -> [ left playerleftgreen]
[ right playerleftgreen] -> [ right Playerrightgreen]
[ left Playerrightyellow] -> [ left playerleftyellow]
[ right playerleftyellow] -> [ right Playerrightyellow]
[ left Playerright] -> [ left playerleft]
[ right Playerleft] -> [ right playerright]

[endx] ->[thefloor] sfx2
[end | thefloor]-> [endx |thefloor]


late up [wall| ]-> [wall|overwall]
late up [theemx| ]-> [theemx|overcrate]

late up [crate2| ]-> [crate2|overcrate2]
late up [crate3| ]-> [crate3|overcrate3]
late up [crate4| ]-> [crate4|overcrate4]

late up [crateg| ]-> [crateg|overcrateg]

late up [crate2g| ]-> [crate2g|overcrate2g]
late up [crate3g| ]-> [crate3g|overcrate3g]
late up [crate4g| ]-> [crate4g|overcrate4g]

late up [end| ]-> [end|overcrate2]
late up [endx| ]-> [endx|overcrate2]

[action player eend|]->[action player eend |crate Target]



[]-> again 
(
[arrow]->[arrowx2]
[arrow2]->[arrowx]

[arrowx]->[arrow]
[arrowx2]->[arrow2])
==============
WINCONDITIONS
==============

no remove
no winend

=======
LEVELS
=======


message remove all blocks

message level 1 of 10
---------
-#######-
-#2...1#-
-#2...1#-
##.....##
#.......#
#..2.1..#
#.......#
#.......#
##..P..##
-#######-

message level 2 of 10
---------
-#######-
##.....##
#33..3..#
###.....#
#33..3..#
###.....#
#22..2..#
#.......#
##..P..##
-#######-

message level 3 of 10
---------
-#######-
##..2..##
#.2...2.#
#...1...#
#.......#
#.1.1.1.#
#.......#
#...1...#
##..P..##
-#######-

message level 4 of 10
---------
-#######-
##.....##
#.3131..#
#.32231.#
#.21131.#
#.......#
#....1..#
#...p.1.#
##....1##
-#######-

message level 5 of 10
---------
-#######-
##22.2.##
#3......#
#3.1234.#
#..4321.#
#3.1234.#
#.......#
#.P.....#
##.....##
-#######-

message level 6 of 10
---------
-#######-
##.212.##
#..121..#
#..313..#
#...3...#
#.#######
#...3.33#
#.P.2.22#
##..1.11#
-########

message level 7 of 10
---------
#########
#.......#
#.21213.#
#.31213.#
#.32121.#
#.......#
#...1...#
#.P..11.#
##.....##
-#######-

message level 8 of 10
---------
#########
#.......#
#..323..#
#.31121.#
#.22312.#
#.31223.#
#..133..#
#.P.....#
##.2.22##
-#######-

message level 9 of 10
---------
-#######-
##.....##
#.23232.#
#.31313.#
#.22122.#
#.......#
#.......#
#.P.2.22#
##.3.33##
-#######-

message level 10 of 10
---------
#########
#.......#
#.34242.#
#.43214.#
#.41432.#
#.14214.#
#.32142.#
#p...4.4#
#.#####4#
###---###

(---------
#########
#.......#
#.31244.#
#.43213.#
#.21432.#
#.34234.#
#.32142.#
#.13231.#
#.P4.44.#
#########)


(---------
#########
#.......#
#..123..#
#.32131.#
#.12313.#
#.13123.#
#..321..#
#.P.....#
##.3.33##
-#######-)


(
---------
-#######-
##3.2.1##
#.3.2.1.#
#.......#
#.3.2.1.#
#.......#
#.3.2.1.#
#44.4.4.#
##..P..##
-#######-
)


xxxxxxxxxxxxxx
-eeeeeeeeeeee-
eeeeeeeeeeeeee
eeeeeeeeeeeeee
wewewewwweweew
wewewetweewwew
weweweeweeweww
eweweewwweweew
eeeeeeeeeeeeee
eeeeeeeeeeeeee
-eeeeeeeeeeee-


