title pretender to the crown
author colin thil
homepage http://pretendertothecrown.wordpress.com/
run_rules_on_level_start
background_color #d7dbef
text_color #69729f
youtube dasz1sSax2k

realtime_interval 0.1
throttle_movement 

========
OBJECTS
========
Exit
red
..0..
..0..
00000
.000.
..0..

snow1
#d7dbef
....0
.....
.....
.....
.....

snow2
#d7dbef
.....
...0.
.....
.....
.....

snow3
#d7dbef
.....
.....
...0.
.....
.....

snow4
#d7dbef
.....
.....
.....
...0.
.....

snow5
#d7dbef
.....
.....
.....
.....
....0

snow6
#d7dbef
.....
.....
.....
.....
....0

Background
#d7dbef #e4e6f4
00100
00000
10000
00000
00001

plant1
#2c5a42 #225039
..0..
.001.
.011.
00111
01111

plant2
#14796c #0c6358
..0..
.001.
.011.
00111
01111

plant3
#2e6549 #225039 #0c6358
22022
20012
20112
00111
01111

plant4
#14796c #0c6358 #225039
22022
20012
20112
00111
01111

crate
LIGHTBROWN BROWN DARKBROWN
00000
01102
01112
02112
22222

player
#ead5a8 #e1c99b #69729f #454b69 #f2c835 #ecbc16
4.4.5
.445.
.011.
.223.
.333.

soldier
#ead5a8 #e1c99b #69729f #454b69 #343b5f #c5c5c4
5.3..
5223.
10044
.0044
.1.1.

prisoner
#ead5a8 #e1c99b #69729f #454b69
..3..
.223.
.000.
.000.
.1.1.

enemy
#ead5a8 #e1c99b #c56c57 #bc5e48 #a7523e #c5c5c4
5.3..
5223.
10044
.0044
.1.1.

UpMarker
RED

LeftMarker
RED

RightMarker
RED

DownMarker
RED


=======
LEGEND
=======
. = Background
p = prisoner
y = plant1
t = plant2
z = plant3
r = plant4
e = enemy
c = crate
x = exit 
a = player

Marker = UpMarker or LeftMarker or RightMarker or DownMarker
crew = Player or soldier or prisoner
plant = plant1 or plant2 or plant3 or plant4
snow = snow1 or snow2 or snow3 or snow4 or snow5 or snow6

=======
SOUNDS
=======

SFX0 52755904 (hit)
SFX1 150500 (rescue)
SFX2 6007707 (push)
SFX3 13396704 (crush)
EndLevel 83714500

================
COLLISIONLAYERS
================

Marker,exit

Background

player,soldier,enemy,prisoner,plant,crate

snow

======
RULES     
======  

random down [no snow|no snow|no snow|no snow|no snow] -> [snow1||||]

[ snow4 ] -> [ snow5 ]
[ snow3 ] -> [ snow4 ]
[ snow2 ] -> [ snow3 ]
[ snow1 ] -> [ snow2 ]
down [ snow6|] -> [ |snow1 ]
[ snow6] -> [  ]
[ snow5 ] -> [ snow6 ]

[ > player | crate] -> [ > player | > crate ] SFX2
[ > crate | crate] -> [ > crate | > crate ] SFX2

left [ > Player | enemy | prisoner ] -> [ player | soldier Rightmarker |  ] SFX0
right [ > Player | enemy | prisoner ] -> [ player | soldier Leftmarker |  ] SFX0
up [ > Player | enemy | prisoner ] -> [ player | soldier Downmarker |  ] SFX0
down [ > Player | enemy | prisoner ] -> [ player | soldier Upmarker |  ] SFX0

[ > Player | enemy | soldier ] -> [ player | | soldier ] SFX0

[ left player ] -> [ left player Leftmarker ]
[ right player ] -> [ right player Rightmarker ]
[ up player ] -> [ up player Upmarker ]
[ down player ] -> [ down player Downmarker ]

startloop
late left [ soldier Leftmarker | No crew ] -> [ Leftmarker | soldier ]
late right [ soldier Rightmarker | No crew ] -> [ Rightmarker | soldier ]
late up [ soldier Upmarker | No crew ] -> [ Upmarker | soldier ]
late down [ soldier Downmarker | No crew ] -> [ Downmarker | soldier ]
endloop

==============
WINCONDITIONS
==============

no prisoner 
some player on exit

=======     
LEVELS
=======

message je suis fatigue, mortellement fatigue
message mais chaque nuit, quand j arrive a dormir, je suis roi de norvege

zrzrzrzrzrz
rzrzrzrzrzr
zrzrz.eperz
rzpzr.tet.r
zre.....z.z
r....a....r
z.y.....etz
r..et.typzr
ztepe.zryrz
rztyt.rzrzr
zrzrzxzrzrz

message depuis ma plus lointaine jeunesse un mal me ronge
message il me faut etre roi, il m’est impossible de vivre autrement!

zrzrzrzrzrz
rzrzrzrzrzr
zrzrprprzrz
rzrzeaezrzr
zrze...ezrz
rzepecepezr
zrye...eyrz
rzryt.tyrzr
zrzrz.zrzrz
rzrzr.rzrzr
zrzrzxzrzrz

message le ciel m a fait pour que je gouverne, il n y a pas d autres remede pour moi
message toi, le tout-puissant, qui m’as mis dans cette situation, il faut que tu assumes les consequences!

zrzrzrzrzrz
rzrz...zrzr
zrze.p.ezrz
rzepeeepezr
zr.ey.ye.rz
a.........x
yt.ey.ye.ty
rzepe.epezr
zrye...eyrz
rzry...yrzr
zrzrytyrzrz

message j’ai vaincu
message d'un coup d'epee, j’ai fait sauter la couronne du roi

zrzrzazrzrz
rzrzr.rzrzr
zrzrz.zrzrz
rprpr.rprpr
zezez.zezez
r.........r
z.yt.e.ty.z
r....e....r
ztyty.ytytz
rzrzr.rzrzr
zrzrzxzrzrz

message Les boucliers etaient enfonces dans la neige mais il n’y avais personnes derriere eux

zrzrzazrzrz
rzrzr.rzrzr
zreez.zeerz
rz..e....zr
zpe.tet.epz
ry..zpz..yr
zpe.rer.epz
rye.....eyr
zreey.yeerz
rztpr.rptzr
zrztzxztzrz

message ils se sont enfuis dans la foret, par les plateux et les marais, et les coteaux
message aussi loin que leurs jambes voulaient les porter

zrzrzazrzrz
rzrzr.rzrzr
zrpe...rzrz
rzty...epzr
zrpe.c.tyrz
rztycycepzr
zrpe.c.tyrz
rzty...epzr
zrzrt.ttyrz
rzrzr.rzrzr
zrzrzxzrzrz

message j’ai defendu l’oeuvre de ma vie et le salut de mon ame

zrzrzazrzrz
rzrzr.rzrzr
zpe.z.z.epz
retyr.r.ter
z..c...c..z
r.t.tyt.t.r
z.z.zrz.z.z
r..c...c..r
zet.y.ytyez
rpe.r.r.epr
ztytzxztttz

message ai-je l’air d un roi maintenant?

rzrzrarzrzr
zpe...zpzpz
ryt..yrerer
zrz..r....z
rzpe...y..r
zry..t..yez
rpr.tpt.rpr
zez.zez.ztz
r...r.r..zr
z..tz...yzz
rzrzrxtyrzr

message chaque jour je doit regarder l’avenir en souriant
message comme si j’etait sur de mon droit, de ma victoire et de mon succes

zrzrzazrzrz
r.........r
z.e.e.e.e.z
rypypypypyr
zryryr.ryrz
rppzpe.epzr
zeeryt..yrz
r...rzt...r
z.y..pe.y.z
r...t.t...r
ztytzxztytz 

message n’y a t’il donc la haut aucune loi certaine sur laquelle tout doit se regler?

zrzrzazrzrz
rprzr.rzrzr
zezpe.epzrz
r..e...erzr
z.y..t..zpz
r...tzt..er
zty.zrz.e.z
rz..r.r...r
zre.....etz
rzptt.ttpzr
zryrzxzryrz

message il y a une peur secrete dans cette victoire

rzrzrarzrzr
z.........z
r..ctyte..r
z.epepepc.z
rytet.tetyr
zpzpz.zpzpz
reryr.ryrer
z..c...c..z
r..y.y.y..r
z..c...c..z
rytztxtztyr

message si j’essaie de me voir comme le juste roi, il faut que je le fasse par artifice,
message par une construction astucieuse, une oeuvre audacieuse

rzrzrarzrzr
zrzrz.zrzrz
rpe.....epr
ztyt.ty.ytz
rpe..c..epr
ztycy.ycytz
rpe..c..epr
zty.y.y.ytz
rzr..cc.rzr
zrztyxytzrz
rzrzrxrzrzr

message le roi etait-il d une autre etoffe que moi?
message serait-il parmis ceux qui ont de la chance?

rzrzrarzrzr
z.....zpe.z
r.t.tcryt.r
z.c.....z.z
r.tytetcr.r
z...cpz...z
retctyr.t.r
zpz.....c.z
ryrctyt.tyr
z...c...epz
rytytxtytyr

message mon royaume?
message il est sombre, comme celui de l’ange qui se dressa contre dieu.

rzrzrarzrzr
zrzr...rzrz
rzpe....epr
zrytccccytz
rpe.....epr
zty.yt.tytz
rpe....epzr
ztycccctyrz
rzpe...epzr
zryt...tyrz
rzrztxtzrrr

message que n ai-je sacrifie pour ce trone ou je ne suis pas parvenu?

rzrzrarzrzr
zrz.....zpz
rz..tct..er
z..t.c.t..z
r.tpecept.r
z.zpecepz.z
r..y.c.y..r
z...ycy..tz
ret.....tzr
zpzty.ytzrz
ryrzrxrzrzr

message je voulais etre le plus grand dans ce pays
message seigneur voyez, je m’humilie devant vous, je suis le plus minable de tous!

rzrzrarzrzr
zrz....rprz
rz...y..ezr
zt.e.r..epz
rpe...ty.yr
zt.ty...epz
rpe..y.e.yr
zte..r...rz
rzpy....tzr
zrzry.ytzrz
rzrzrxrzrzr

message je suis un pauvre homme, je n’ais que ma vie a donner
message prennez la et sauvez la pensee royale
message -vous avez perdu-