title Sliding ground
author Rosden Shadow [Mark Signorelli]
homepage rosden.itch.io

noaction
run_rules_on_level_Start

background_color #423D39

text_color #FFD9E0

again_interval 0.075
========
OBJECTS
========

Background
#736053 #423D39 (#E57ED5 #CC5285)
11111
10101
10001
10101
11111
(
00101
01110
11011
01111
10110)
(
11101
00101
11111
10100
10111)

Backtile
#7EA1E5 #46495B (#E57ED5 #CC5285)
11111
11011
10001
11011
11111

Backtile2
#7EA1E5 #46495B (#E57ED5 #CC5285)
11111
11011
10001
11011
11111

Backtile12
#7EE58D #4F5B46 (#E57ED5 #CC5285)
11111
11011
10101
11011
11111

Backtile22
#7EE58D #4F5B46 (#E57ED5 #CC5285)
11111
11011
10101
11011
11111


nomove
#FFEED9 #536673
.....
.000.
.010.
.000.
.....

Target
white #423D39
.....
.010.
.101.
.010.
.....

Wall
#F2F2AA #E5C17E  #CC7A52 #736053
21110
21110
22221
23232
32323

overwall
#F2F2AA #E5C17E #CC7A52 #736053
.....
.....
.....
10000
21110


Playerright
#FFFFFF #CCCCCC #F2AACE #E57ED5
.000.
11202
11313
11110
.1.1.

playerleft
#FFFFFF #CCCCCC #F2AACE #E57ED5
.000.
20211
31311
01111
.1.1.

Crate
#FFD9E0 #E0AAF2 #A87EE5 #705C84
21100
21110
22110
32223
.333.

overcrate
#FFD9E0 #E0AAF2 #A87EE5 #705C84
.....
.....
.....
.....
.000.

end
#FFD9E0 #E0AAF2 #A87EE5 #705C84
21100
21110
22110
32223
.333.
endx
#FFD9E0 #E0AAF2 #A87EE5 #705C84
21100
21110
22110
32223
.333.



cloner
#E5C17E #DB7F55 #B32D2D #73342E
.100.
.210.
.221.
.332.
.....

swapcrate
Orange Yellow
00000
0...0
0...0
0...0
00000

swapwall
black
.....
.....
.....
.....
.....

thefloor
#423D39
00000
00000
00000
00000
00000

thefloorx
#423D39
00000
00000
00000
00000
00000

eend
#423D39
00000
00000
00000
00000
00000
(
checkempty
black
.....
.....
.....
.....
.....

checkblock
black
.....
.....
.....
.....
.....
)
tilemov
TRANSPARENT

tdown
TRANSPARENT
tup
TRANSPARENT
tleft
TRANSPARENT
tright
TRANSPARENT

moved
TRANSPARENT
pithide
TRANSPARENT

pit
black #231F26 (#E57ED5 #CC5285)
11111
10101
01010
00000
00000

pitfull
black #231F26 (#E57ED5 #CC5285)
00000
00000
00000
00000
00000


switcrate
black
.....
.....
.....
.....
.....

switcrate2
black
.....
.....
.....
.....
.....

arrow
black
.....
.....
.0.0.
.000.
..0..

arrow2
black
.....
.0.0.
.000.
..0..
.....

arrowx
black
.....
.....
.....
.....
.....

arrowx2
black
.....
.....
.....
.....
.....

winend
#F2F2AA #E5C17E  #CC7A52 #736053
1000.
21100
21110
22110
.2221


=======
LEGEND
=======

. = Background
# = Wall
P = Playerright
* = Crate

@=Backtile and pithide
$=Backtile12 and pithide

O = Target
n = nomove
a = arrow2 and wall
e=end
t = end and target and eend
w=end and winend

c=cloner
-=thefloor
x=thefloorx

'=pit

feel=overwall or overcrate 
pushable=crate or cloner or swapcrate  or switcrate or switcrate2
win=crate or wall


theemx= crate 
player=playerright or playerleft

blocker = wall or crate  or nomove or player or arrow

arrowk = arrow or arrow2 or arrowx or arrowx2

apit = pit or pitfull

timove=tdown or tup or tleft or tright

tiles=Backtile or Backtile2 or Backtile12 or Backtile22
pltile=Backtile2 or Backtile22

lettile1=Backtile or Backtile2 or apit
lettile2=Backtile12 or Backtile22 or apit
=======
SOUNDS
=======

pushable MOVE 36772507

EndLevel 74089700

player MOVE 68988304
sfx0 52836103
sfx1 45427502

sfx2 29503700
sfx3 81951902

sfx4 85005707

sfx5 46007707

sfx6 72127307
================
COLLISIONLAYERS
================

Background

apit
pithide

backtile
backtile2

Backtile12
backtile22

Target
nomove
Player, Wall, pushable,swapwall,thefloor,thefloorx


moved
timove
tilemov
arrow, arrow2, arrowx, arrowx2
winend
eend
end, endx
feel


======
RULES
======

[feel]->[]


[ >  Player | crate] -> [  >  Player | > crate]

[> crate|apit]->[crate|apit]

(rigid)
([> player Backtile |apit]->[pit| player backtile] sfx4)

([> player  Backtile |apit]->[> player > backtile|apit ] sfx4)

[tilemov]->[]
[timove]->[]
[moved]->[]

[player]->[player tilemov]

[> player no pltile|apit]->[player |apit]


[> player  Backtile2  tilemov|apit no backtile]->[> player  > backtile2 |apit] sfx6

[player backtile]->[player backtile2]
[backtile2 no player] ->[backtile]

(rigid [> player tilemov Backtile]->[> player > backtile > tilemov] sfx4)
rigid [ Moving player backtile2 no tilemov| backtile ] -> [ Moving player Backtile2  | MOVING backtile ]
+rigid [ Moving backtile | backtile ] -> [ Moving backtile | MOVING backtile ]

[right backtile]->[right backtile tright] 
[down backtile]->[down backtile tdown] 
[up backtile]->[up backtile tup] 
[left backtile]->[left backtile tleft] 


[> player  Backtile22  tilemov|apit no backtile12]->[> player  > backtile22 |apit] sfx5
 
[player backtile12]->[player backtile22]
[backtile22 no player] ->[backtile12]

(rigid [> player tilemov Backtile]->[> player > backtile > tilemov] sfx4)
rigid [ Moving player backtile22 no tilemov| backtile12 ] -> [ Moving player Backtile22  | MOVING backtile12 ]
+rigid [ Moving backtile12 | backtile12 ] -> [ Moving backtile12 | MOVING backtile12 ]

[right backtile12]->[right backtile12 tright]
[down backtile12]->[down backtile12 tdown]
[up backtile12]->[up backtile12 tup]
[left backtile12]->[left backtile12 tleft]



late right[crate tright no moved|]->[tright|crate moved] 
late left[crate tleft no moved|]->[tleft|crate moved] 
late up[crate tup no moved|]->[tup|crate moved] 
late down[crate tdown no moved|]->[tdown|crate moved] 

[> backtile|no lettile1]->cancel
[> backtile12|no lettile2]->cancel


late [tiles apit]->[tiles pithide]
late [pithide no tiles]->[pit]

(+rigid left[left backtile|no apit]->[ backtile|]
+rigid right[right backtile|no apit]->[ backtile|]
+rigid up[up backtile|no apit]->[ backtile|]
+rigid down[down backtile|no apit]->[ backtile|])

([> backtile|apit]->[> backtile|])
(rigid [ > Player | crate ] -> [> Player | > crate  ]  )   

[> crate|Target]->[> crate|target] sfx2

[ left Playerright] -> [ left playerleft]
[ right Playerleft] -> [ right playerright]

[endx] ->[thefloor] sfx2
[end | thefloor]-> [endx |thefloor]


late up [wall| ]-> [wall|overwall]
late up [theemx| ]-> [theemx|overcrate]

(late up [crate2| ]-> [crate2|overcrate2])
late up [end| ]-> [end|overcrate]
late up [endx| ]-> [endx|overcrate]

late up [apit|apit]->[pitfull|apit]

late up [apit|no apit]->[pit|]

([action player eend|]->[action player eend |crate Target])



[]-> again 
(
[arrow]->[arrowx2]
[arrow2]->[arrowx]

[arrowx]->[arrow]
[arrowx2]->[arrow2])
==============
WINCONDITIONS
==============

all Target on crate 

some target
=======
LEVELS
=======

message Have a crate on all targets

message level 1 of 9
---------
-#######-
-#.....#-
##'.*.'##
#'''''''#
#'''''''#
#''@@@''#
#'''P'''#
##''O''##
-#'''''#-
-#######-

message level 2 of 9
---------
-#######-
##'''''##
#'''*'''#
#'''.'''#
#'''''''#
#'''$'''#
#''$P$''#
#'''O'''#
##'''''##
-#######-

message level 3 of 9
---------
#########
#'''#'''#
#'O'.'*'#
#'''''@'#
#'@@''@'#
#'''''''#
#'''''''#
#'@'P@''#
#'''''''#
#########

message level 4 of 9
---------
-#######-
##'''''##
#'''*'''#
#'''''''#
#'.'''.'#
#''@'$''#
#''@P$''#
#'''O'''#
##'''''##
-#######-


message level 5 of 9
---------
-#######-
##'OPO'##
#'''$'''#
##$'''$##
-##'''##-
-##'''##-
-#$'''$#-
-#.*.*.#-
-#'...'#-
-#######-

message level 6 of 9
---------
#########
#''''''O#
#''''''$#
#''####'#
#'''''.##
#''$.'..#
#'''P'*.#
#''$.'..#
##''''.##
-#######-

message level 7 of 9
---------
-#######-
##'''''##
#'@*.*@'#
#'''.'''#
#'''''''#
#O'''''O#
#'''@'''#
#'''P'''#
##'''''##
-#######-

message level 8 of 9
---------
#########
#'*'#'O'#
#'''#'''#
#'''#'''#
#'$'''''#
#'''''''#
#'$'''''#
#'$'P@''#
#'''''''#
#########


message level 9 of 9
---------
#########
#O''''''#
#'''''''#
#####'''#
#..@''''#
#P.$''''#
#..@''''#
#..$'*''#
##.....##
-#######-


(---------
#########
#''''''O#
#''''''$#
#''####'#
#''''@.##
#''''$.P#
#''''@..#
#''*'$..#
##.....##
-#######-)

(---------
-#######-
#OO##$'##
#''$#'''#
#''##'**#
#''#''''#
#'''''''#
#'''''$$#
#'''@'P'#
##'''''##
-#######-)


(---------
-#######-
##'''''##
#'''*'''#
#'''''''#
#'@@'$$'#
#@..'..$#
#'..P..'#
#'''O'''#
##'''''##
-#######-)


(---------
-#######-
##'''''##
#'''*'''#
#'''''''#
#'''''''#
#'''''''#
#'''P'''#
#'''O'''#
##'''''##
-#######-)




xxxxxxxxxxxxxx
-eeeeeeeeeeee-
eeeeeeeeeeeeee
eeeeeeeeeeeeee
wewewewwweweew
wewewetweewwew
weweweeweeweww
eweweewwweweew
eeeeeeeeeeeeee
eeeeeeeeeeeeee
-eeeeeeeeeeee-


